Mécanisme de Peaucellier
Auteur ou autrice : Maxime Chupin.
Mise en ligne le 11 février 2026
Animation du mécanisme de Peaucellier qui transforme un mouvement rotatif en mouvement parfaitement rectiligne et réciproquement. Il faut inventé en 1864 et il s’agit du premier dispositif plan permettant une telle transformation.
Soit $O$ et $A$ deux points fixes distants de $a$. On considère un point $P$ en rotation autour du $A$ à une distance de $a$ de celui-ci. On définit ensuite deux points $N_1$ et $N_2$ tous deux distants de $c$ de $O$ et de $b$ de $P$. On construit enfin le point $M$ distant de $b$ de $N_1$ et de $N_2$. Lorsque $P$ évolution en rotation, $M$ décrit un mouvement rectiligne.
Code
%@author: Maxime Chupin
%@date: 2026/02/10
prologues := 3;
outputtemplate := "svg/%j-%c.svg";
outputformat := "svg";
input geom2d;
a:=1;
b:=1.5a;
c:=3.0a;
O = Point(0,0);
A = Point(a,0);
nbrImg := 100;
angleMax :=80;
epaisseur := 2.5;
for i=0 upto 2*nbrImg:
beginfig(i);
if(i<=nbrImg):
rot := -angleMax+(i/nbrImg)*2*angleMax;
else:
rot := angleMax-((i-nbrImg)/nbrImg)*2*angleMax;
fi
P := Addition(A,Point(a*cosd(rot),a*sind(rot)));
CP := Cercle(P,b);
CO := Cercle(O,c);
N1 := IntersectionCercles(CO,CP);
N2 := IntersectionCercles(CP,CO);
CN1 := Cercle(N1,b);
CN2 := Cercle(N2,b);
M := IntersectionCercles(CN1,CN2);
drawoptions(avecCrayon(0.8,DarkGrey));
trace AxeOx;
trace Droite(Point(Abscisse(M),0),Point(Abscisse(M),3));
drawoptions(avecCrayon(epaisseur,Goldenrod));
trace Segment(O,A);
trace Segment(A,P);
drawoptions(avecCrayon(epaisseur,FireBrick));
trace Segment(P,N1);
trace Segment(P,N2);
trace Segment(M,N1);
trace Segment(M,N2);
drawoptions(avecCrayon(epaisseur,DarkSeaGreen));
trace Segment(O,N1);
trace Segment(O,N2);
drawoptions();
marque.bot "O";
marque.bot "A";
marque.rt "P";
gddLabel.top(textext("$N_1$"),N1);
gddLabel.bot(textext("$N_2$"),N2);
pointe N1; pointe N2;
marque.rt "M";
Fenetre(-0.4,-3.2,4.5,3.2);
endfig;
endfor;
end.
Mots clés : animationmécanismerotationinversion